dnl
dnl Check for lib pthread by seeing if __pthread_initialize exists.
dnl
AC_DEFUN(CHECK_LIB_PTHREAD,
[
 AC_CHECK_LIB(pthread, __pthread_initialize,
 [
  AC_DEFINE(HAVE_LIB_PTHREAD, 1, [Define if you have pthreads in your glibc])
  LIBS="-lpthread $LIBS"
 ])
])

dnl
dnl Java Like Threads For C++ from IONA.com (Used with ORBacus)
dnl
dnl Check for lib JTC exists by seeing if JTC Monitor and JTCSynchronized
dnl exist.
dnl
AC_DEFUN(CHECK_LIB_JTC,
[
	AC_MSG_CHECKING(for -lJTC)
	AC_LANG_PUSH(C++)
	my_check_lib_jtc_save_LIBS=$LIBS
	LIBS="-lJTC $LIBS"
	AC_TRY_LINK(
	[#include "JTC/JTC.h"],
	[
		JTCMonitor test;
		JTCSynchronized t(test);
	], 
	[
		lib_jtc_found=yes
	], 
	[
		lib_jtc_found=no
	])
	LIBS=$my_check_lib_jtc_save_LIBS
	AS_IF(
	[test x$lib_jtc_found = xyes],
      	[
	 AC_DEFINE(HAVE_LIB_JTC, 1, [Define if you have the JTC library.])
	 LIBS="-lJTC $LIBS"
	 AC_MSG_RESULT($lib_jtc_found)
	],
	[
	 AC_MSG_RESULT($lib_jtc_found)
	])
AC_LANG_POP(C++)
])

dnl
dnl ORBacus from IONA
dnl
dnl Check for lib OB by seeing if String_var exists.
dnl
AC_DEFUN(CHECK_LIB_OB,
[
	AC_MSG_CHECKING(for -lOB)
	AC_LANG_PUSH(C++)
	my_check_lib_ob_save_LIBS=$LIBS
	LIBS="-lOB $LIBS"
	AC_TRY_LINK(
	[#include<OB/CORBA.h>],
	[
		CORBA::String_var test;
	], 
	[
		lib_ob_found=yes
	], 
	[
		lib_ob_found=no
	])
	LIBS=$my_check_lib_ob_save_LIBS
	AS_IF(
	 [test x$lib_ob_found = xyes],
      	 [
	  AC_DEFINE(HAVE_LIB_OB, 1, [Define if you have the ORBacus library.])
	  LIBS="-lOB $LIBS"
	  AC_MSG_RESULT($lib_ob_found)
	 ],
	 [
	  AC_MSG_RESULT($lib_ob_found)
	 ])
AC_LANG_POP(C++)
])

dnl
dnl Check for lib CosNaming if NamingContext_ptr exists.
dnl
AC_DEFUN(CHECK_LIB_COSNAMING,
[
	AC_MSG_CHECKING(for -lCosNaming)
	AC_LANG_PUSH(C++)
	my_check_lib_cosnaming_save_LIBS=$LIBS
	LIBS="-lCosNaming $LIBS"
	AC_TRY_LINK(
	[#include "OB/CORBA.h"
	 #include "OB/CosNaming.h"
	], 
	[
		CosNaming::NamingContext_ptr test;
	],
	[
		lib_cosnaming_found=yes
	], 
	[
		lib_cosnaming_found=no
	])
	LIBS=$my_check_lib_cosnaming_save_LIBS
	AS_IF(
	 [test x$lib_cosnaming_found = xyes],
      	 [
	  AC_DEFINE(HAVE_LIB_COSNAMING, 1, [Define if you have the ORBacus CosNaming library.])
	  LIBS="-lCosNaming $LIBS"
	  AC_MSG_RESULT($lib_cosnaming_found)
	 ],
	 [
	  AC_MSG_RESULT($lib_cosnaming_found)
	 ])
AC_LANG_POP(C++)
])